博客园_广氏波罗猫技术研习社

AirExcel －用于导出 Excel 2007 文件的 Flex AIR 组件初版发布

2010-10-30T03:25:00Z

AirExcel －用于导出 Excel 2007 文件的 Flex AIR 组件初版发布

版本日期：2010年10月30日

功能：

每个工作薄 (Workbook) 可以添加无限数量的试算表 (Sheet)
试算表不限行数，列数从 A 到 ZZ 共 702 列
单元格内容支持文本、数值
可以写入文件 (flash.filesystem.File 对象)，写入完毕会分派 Event.COMPLETE 事件

限制：

仅限 AIR 桌面程序使用
暂只能把数据按行写入文件，未能从文件读取数据
日期会被处理为文本（类似 1997-09-30 14:07:00）
其他对象会被处理为字符串 [object]
XML节点会被处理为空字符串，因此处理前请做强制类型转换

用法示例：

A. Flex AIR 界面组件：

<s:Button x="83" y="53" label="按钮" id="btnOK" click="btnOK_clickHandler(event)"/>
<s:Label x="83" y="110" width="371" height="25" id="lblMessage"/>

B. Flex 脚本：

            import mx.formatters.DateFormatter;
            import nonamecat.excel.ExcelWorkbook;

            protected function btnOK_clickHandler(event:MouseEvent):void
            {
                var excel:ExcelWorkbook = new ExcelWorkbook();
                excel.addEventListener(Event.COMPLETE, onCompleteHandler);

                var sheet:XML = excel.createSheet("你好");

                var sheet2:XML = excel.createSheet("World");

                var sheet3:XML = excel.createSheet("Sheet3");

                var o:Object = new Object();

                o.a = "Hello";
                o.b = 1;
                o.c = 3.3;
                o.d = new Date();

                excel.appendRow(sheet, o.a, o.a, o.b, o.c, o.d);
                excel.appendRow(sheet, "abc","111222", 220.99, "Hello");

                excel.appendRow(sheet2, "abcdefg", "111222", "220.99", "xxdef", "xxHello");

                excel.appendRow(sheet3, o.a, o.a, o.b, o.c, o.d);

                var file:File = new File("D:\\abc.xlsx");

                excel.write(file);
            }

            private function onCompleteHandler(event:Event):void
            {
                var df:DateFormatter = new DateFormatter();
                df.formatString = "YYYY年MM月DD日 HH点NN分SS秒";
                this.lblMessage.text = "创建 Excel 文件完毕－ "+ df.format(new Date());
            }

下载：

AirExcel.swc.rar

本文链接

Flex SQLite Batch Insert Datas from Array

2010-07-27T00:19:00Z

        [Bindable(event="message")]
        private function dbSyncData():void
        {

            stmt.addEventListener(SQLEvent.RESULT, dbExecuteBatchSQL);

            var dataArray:Array = this.params.SyncDataArray as Array;

            if(dataArray == null){
                dispatchEvent(new MessagesEvent("同步到 SQLite","失败：数据源记录集是空的。"));
                return;
            }

            var dataTable:String = this.params.SyncDataTable as String;

            if(dataTable == null){
                dispatchEvent(new MessagesEvent("同步到 SQLite","失败：数据表名称未定义。"));
                return;
            }

            dispatchEvent(new MessagesEvent("同步到 SQLite","准备将 "+ dataArray.length +" 条记录同步到 "+ dataTable +" 数据表"));

            this._execSQLBatch = new Array();

            if(dataTable == "stockdaily"){
                for(var i:int=0;i<dataArray.length;i++){
                    var o:Object = dataArray[i];
                    var sql:String = "INSERT INTO stockdaily (StatDate,Symbol,FinalPrice,HighPrice,LowPrice,DealVolume,DealMoney,RunDate) "+
                        " VALUES ('@StatDate','@Symbol',@FinalPrice,@HighPrice,@LowPrice,@DealVolume,@DealMoney,'@RunDate')"
                        .replace("@StatDate", o["StatDate"])
                        .replace("@Symbol", o["Symbol"])
                        .replace("@FinalPrice", o["FinalPrice"])
                        .replace("@HighPrice", o["HighPrice"])
                        .replace("@LowPrice", o["LowPrice"])
                        .replace("@DealVolume", o["DealVolume"])
                        .replace("@DealMoney", o["DealMoney"])
                        .replace("@RunDate", o["RunDate"])
                        ;
                    this._execSQLBatch.push(sql);
                }
            }else if(dataTable == "stockdailywatch"){
                for(var i:int=0;i<dataArray.length;i++){
                    var o:Object = dataArray[i];
                    var sql:String = "INSERT INTO stockdailywatch (Symbol,Name) VALUES ('@Symbol','@Name')"
                        .replace("@StatDate", o["StatDate"])
                        .replace("@Name", o["Name"])
                        ;
                    this._execSQLBatch.push(sql);
                }
            }

            this._execSQLCallLatency = this.dbSyncDataResult;

            this.dbExecuteBatchSQL(null);

        }

        private function dbSyncData():void
        {
            dispatchEvent(new MessagesEvent("同步到 SQLite","同步数据完毕。"));
        }

本文链接

Flex 遍历 ArrayCollection, Array

2010-07-26T09:33:00Z

//Array:

for(var i:int=0;i<result.data.length;i++){
    var o:Object = result.data[i];
    trace(o["Symbol"],o["FinalPrice"],o["RunDate"]);
}

//ArrayCollection:

var c:ArrayCollection = new ArrayCollection(result.data);

for(var i:int=0;i<c.length;i++){
    var o:Object = c.getItemAt(i);
    trace(o["Symbol"],o["FinalPrice"],o["RunDate"]);
}

本文链接

Flex SQLite: 一次执行多个SQL，查询两个表的数据，导入datagrid

2010-07-26T05:28:00Z

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
                       xmlns:s="library://ns.adobe.com/flex/spark"
                       xmlns:mx="library://ns.adobe.com/flex/mx">
    <fx:Declarations>
        
    </fx:Declarations>
    <fx:Script>
        <![CDATA[
            import mx.collections.ArrayCollection;
            private var con:SQLConnection;
            private var stmt:SQLStatement;
            private var dbFile:File = File.documentsDirectory.resolvePath("MacroEconomicResearchData.sqlite.db");

            /**
             * 打开文件选择对话框，选择 DB 文件
             */
            protected function selectDBFile(root:File):void
            {
                try
                {
                    root.browseForSave("打开 DB 文件");
                    root.addEventListener(Event.SELECT, checkDBFileFormat);
                }
                catch(error:Error)
                {
                    trace("打开失败：" + error.message);
                }
            }

            /**
             * 以字节流方式读取文件内容，检查文件是否 SQLite 格式
             */
            protected function checkDBFileFormat(event:Event):void
            {
                if(this.dbFile.exists)
                {
                    var stream:FileStream = new FileStream();
                    stream.open(this.dbFile, FileMode.READ);
                    var s:String = stream.readUTFBytes(20);
                    if(s.substr(0,16) == "SQLite format 3"){
                        stream.close();
                        trace("db file format ok fit");

                        this.openDBFile();
                    }else{
                        stream.close();
                        trace("db file format not fit");
                        this.dbFile = File.documentsDirectory.resolvePath("MacroEconomicResearchData.sqlite.db");
                    }
                }
                else
                {
                    trace("new file");
                    this.openDBFile();
                }

            }

            /**
             * 以数据库方式异步打开文件
             */
            private function openDBFile():void{


                con = new SQLConnection();

                con.addEventListener(SQLEvent.OPEN, dbInitStruct);
                con.addEventListener(SQLErrorEvent.ERROR, dbErrorHandler);

                con.openAsync(this.dbFile);
            }

            /**
             * 数据库访问错误处理程式
             */
            private function dbErrorHandler(event:SQLErrorEvent):void
            {
                trace("Error message:", event.error.message);
                trace("error Details:", event.error.details);
            }

            /**
             * 批量SQL集合的游标指针
             */
            private var _execSQLCount:int = 0;
            /**
             * 批量SQL集合数组，不能用 ArrayList
             */
            private var _execSQLBatch:Array = new Array();
            /**
             * 执行完毕全部SQL语句后要调用的函数（无参数）
             */
            private var _execSQLCallLatency:Function;

            /**
             * 批量执行SQL语句
             */
            private function dbExecuteBatchSQL(evt:SQLEvent):void{
                this._execSQLCount++;

                trace(this._execSQLCount , this._execSQLBatch.length);

                if(this._execSQLCount > this._execSQLBatch.length){

                    this._execSQLCount = 0;
                    this.stmt.removeEventListener(SQLEvent.RESULT, dbExecuteBatchSQL);

                    if(this._execSQLCallLatency != null)
                    {
                        this._execSQLCallLatency.call();
                        //this._execSQLCallLatency = null;  DO NOT SET TO NULL, OR IT WILL NOT RUN
                    }
                }else{
                    var sql:String = this._execSQLBatch[this._execSQLCount-1] as String;
                    trace(sql);
                    this.stmt.text = sql;
                    this.stmt.execute();
                }
            }

            /**
             * 数据结构初始化，建立三个数据表
             */
            private function dbInitStruct(evt:SQLEvent):void
            {


                this._execSQLBatch = new Array();
                this._execSQLBatch.push("CREATE TABLE IF NOT EXISTS stockdaily (" +
                    "    ID INTEGER PRIMARY KEY AUTOINCREMENT, " +
                    "    StatDate DATE," +
                    "    Symbol VARCHAR(30)," +
                    "    FinalPrice FLOAT," +
                    "    HighPrice FLOAT," +
                    "    LowPrice FLOAT," +
                    "    DealVolume FLOAT," +
                    "    DealMoney FLOAT," +
                    "    RunDate DATETIME" +
                    ");");
                this._execSQLBatch.push("CREATE TABLE IF NOT EXISTS stockdailywatch (" +
                    "    ID INTEGER PRIMARY KEY AUTOINCREMENT, " +
                    "    Symbol VARCHAR(30)," +
                    "    Name VARCHAR(30)" +
                    ");");
                this._execSQLBatch.push("CREATE TABLE IF NOT EXISTS stockmarketdaily (" +
                    "    ID INTEGER PRIMARY KEY AUTOINCREMENT, " +
                    "    StatDate DATE," +
                    "    SHDealMoney FLOAT(8,2)," +
                    "    SZDealMoney FLOAT(8,2)," +
                    "    SHDealMoneyComp FLOAT(6,2)," +
                    "    SZDealMoneyComp FLOAT(6,2)," +
                    "    SHAvgPE FLOAT(6,2)," +
                    "    SZAvgPE FLOAT(6,2)," +
                    "    SHAvgPB FLOAT(6,2)," +
                    "    SZAvgPB FLOAT(6,2)," +
                    "    SHAvgPrice FLOAT(7,2)," +
                    "    SZAvgPrice FLOAT(7,2)," +
                    "    RunDateTime DATETIME" +
                    ");");


                this.stmt = new SQLStatement();
                this.stmt.sqlConnection = con;
                this.stmt.addEventListener(SQLErrorEvent.ERROR, dbErrorHandler);

                this.stmt.addEventListener(SQLEvent.RESULT, dbExecuteBatchSQL);

                this._execSQLCallLatency = this.dbInitData;

                this.dbExecuteBatchSQL(null);

            }

            /**
             * 数据初始化，插入两条记录
             */
            private function dbInitData(event:SQLEvent=null):void
            {
                trace("SQLite 数据库初始化完成");


                stmt.addEventListener(SQLEvent.RESULT, dbExecuteBatchSQL);

                this._execSQLBatch = new Array();

                this._execSQLBatch.push("INSERT INTO stockdailywatch (Symbol,Name) VALUES ('1A0001','上证指数')");
                this._execSQLBatch.push("INSERT INTO stockdaily (StatDate,Symbol,FinalPrice,RunDate) VALUES (date('2010-7-26'),'600066',16.00,date('now'))");

                this._execSQLCallLatency = this.dbQueryData;

                this.dbExecuteBatchSQL(null);

            }

            /**
             * 从两个数据表中查询内容
             */
            private function dbQueryData(event:SQLEvent=null):void
            {
                trace("SQLite 数据插入完成");

                this.dbQueryONE();
                this.dbQueryTWO();

            }

            /**
             * 发起查询第一个数据表的内容
             */
            private function dbQueryONE():void{
                var stmt:SQLStatement = new SQLStatement();
                stmt.sqlConnection = this.con;

                stmt.text = "SELECT Symbol,Name FROM stockdailywatch";
                stmt.execute(-1, new Responder(dbShowDataONE, dbErrorHandler));
            }

            /**
             * 发起查询第二个数据表的内容
             */
            private function dbQueryTWO():void{
                var stmt:SQLStatement = new SQLStatement();
                stmt.sqlConnection = this.con;

                stmt.text = "SELECT Symbol,FinalPrice,RunDate FROM stockdaily";
                stmt.execute(-1, new Responder(dbShowDataTWO, dbErrorHandler));
            }


            /**
             * 获得第一个数据表的查询结果，导入 datagrid
             */
            private function dbShowDataONE(result:SQLResult):void
            {
                trace("ONE 查询成功, 影响"+result.rowsAffected+"条记录");


                if(result.data!=null )
                {
                    trace("ONE 得到"+result.data.length + "个结果");
                    var c:ArrayCollection = new ArrayCollection(result.data);
                    var numResults:int =result.data.length;
                    this.dgOne.dataProvider = c;
                }

            }

            /**
             * 获得第二个数据表的查询结果，导入 datagrid
             */
            private function dbShowDataTWO(result:SQLResult):void
            {
                trace("TWO 查询成功, 影响"+result.rowsAffected+"条记录");


                if(result.data!=null )
                {
                    trace("TWO 得到"+result.data.length + "个结果");
                    var c:ArrayCollection = new ArrayCollection(result.data);
                    var numResults:int =result.data.length;
                    this.dgTwo.dataProvider = c;
                }

            }


            /**
             * 按钮点击事件，触发以上全部过程
             */
            protected function btnOK_clickHandler(event:MouseEvent):void
            {
                this.selectDBFile(this.dbFile);
            }

        ]]>
    </fx:Script>
    <s:Button x="210" y="10" label="按钮" id="btnOK" click="btnOK_clickHandler(event)"/>
    <mx:DataGrid x="10" y="46" width="426" id="dgOne">
        <mx:columns>
            <mx:DataGridColumn headerText="ID" dataField="ID"/>
            <mx:DataGridColumn headerText="Symbol" dataField="Symbol"/>
            <mx:DataGridColumn headerText="Name" dataField="Name"/>
            </mx:columns>
    </mx:DataGrid>
    <mx:DataGrid x="10" y="210" width="426" id="dgTwo">
        <mx:columns>
            <mx:DataGridColumn headerText="RunDate" dataField="RunDate"/>
            <mx:DataGridColumn headerText="Symbol" dataField="Symbol"/>
            <mx:DataGridColumn headerText="FinalPrice" dataField="FinalPrice"/>
        </mx:columns>
    </mx:DataGrid>


</s:WindowedApplication>

本文链接

Flex AIR SQLite

2010-07-21T23:37:00Z

直接帖代码

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
                       xmlns:s="library://ns.adobe.com/flex/spark"
                       xmlns:mx="library://ns.adobe.com/flex/mx" xmlns:doug="com.dougmccune.containers.*" width="700" height="600">
    <fx:Declarations>
        
    </fx:Declarations>
    <fx:Script>
        <![CDATA[
            import mx.collections.ArrayCollection;

            protected function cbLocal_changeHandler(event:Event):void
            {
                if(this.cbLocal.selected){
                    this.viewDataSource.selectedIndex = 1
                }else{
                    this.viewDataSource.selectedIndex = 0;
                }
            }

            import mx.controls.Alert;
            private var con:SQLConnection;
            private var stmt:SQLStatement;
            private var dbFile:File = File.documentsDirectory.resolvePath("MacroEconomicResearchData.sqlite.db");

            protected function btnOpen_clickHandler(event:MouseEvent):void
            {
                this.selectDBFile(this.dbFile);


            }


            protected function selectDBFile(root:File):void
            {
                try
                {
                    root.browseForSave("打开 DB 文件");
                    root.addEventListener(Event.SELECT, checkDBFileFormat);
                }
                catch(error:Error)
                {
                    trace("打开失败：" + error.message);
                }
            }

            protected function checkDBFileFormat(event:Event):void
            {
                if(this.dbFile.exists)
                {
                    var stream:FileStream = new FileStream();
                    stream.open(this.dbFile, FileMode.READ);
                    var s:String = stream.readUTFBytes(20);
                    if(s.substr(0,16) == "SQLite format 3"){
                        stream.close();
                        trace("db file format ok fit");

                        this.openDBFile();
                    }else{
                        stream.close();
                        trace("db file format not fit");
                        this.dbFile = File.documentsDirectory.resolvePath("MacroEconomicResearchData.sqlite.db");
                    }
                }
                else
                {
                    trace("new file");
                    this.openDBFile();
                }

            }

            private function openDBFile():void{


                con = new SQLConnection();

                con.addEventListener(SQLEvent.OPEN, dbInitStruct);
                con.addEventListener(SQLErrorEvent.ERROR, dbErrorHandler);

                con.openAsync(this.dbFile);
            }

            private function dbErrorHandler(event:SQLErrorEvent):void
            {
                trace("Error message:", event.error.message);
                trace("error Details:", event.error.details);
            }

            private function dbInitStruct(evt:SQLEvent):void
            {

                stmt = new SQLStatement();
                stmt.sqlConnection = con;
                var sql:String =
                    /*
                    "CREATE TABLE IF NOT EXISTS stockdaily (" +
                    "    ID INTEGER PRIMARY KEY AUTOINCREMENT, " +
                    "    StatDate DATE," +
                    "    Symbol VARCHAR(30)," +
                    "    FinalPrice FLOAT," +
                    "    HighPrice FLOAT," +
                    "    LowPrice FLOAT," +
                    "    DealVolume FLOAT," +
                    "    DealMoney FLOAT," +
                    "    RunDate DATETIME" +
                    ");"+
                    */
                    "CREATE TABLE IF NOT EXISTS stockdailywatch (" +
                    "    ID INTEGER PRIMARY KEY AUTOINCREMENT, " +
                    "    Symbol VARCHAR(30)," +
                    "    Name VARCHAR(30)" +
                    ");"
                    /*
                    +
                    "CREATE TABLE IF NOT EXISTS stockmarketdaily (" +
                    "    ID INTEGER PRIMARY KEY AUTOINCREMENT, " +
                    "    StatDate DATE," +
                    "    SHDealMoney FLOAT(8,2)," +
                    "    SZDealMoney FLOAT(8,2)," +
                    "    SHDealMoneyComp FLOAT(6,2)," +
                    "    SZDealMoneyComp FLOAT(6,2)," +
                    "    SHAvgPE FLOAT(6,2)," +
                    "    SZAvgPE FLOAT(6,2)," +
                    "    SHAvgPB FLOAT(6,2)," +
                    "    SZAvgPB FLOAT(6,2)," +
                    "    SHAvgPrice FLOAT(7,2)," +
                    "    SZAvgPrice FLOAT(7,2)," +
                    "    RunDateTime DATETIME" +
                    ");"
                    */

                stmt.text = sql;
                stmt.addEventListener(SQLEvent.RESULT, dbInitData);
                stmt.addEventListener(SQLErrorEvent.ERROR, dbErrorHandler);
                stmt.execute();

            }

            private function dbInitData(event:SQLEvent):void
            {
                trace("SQLite 数据库初始化完成");

                stmt.removeEventListener(SQLEvent.RESULT, dbInitData);
                stmt.addEventListener(SQLEvent.RESULT, dbQueryData);
                stmt.text = "INSERT INTO stockdailywatch (Symbol,Name) VALUES ('1A0001','上证指数')";
                stmt.execute();

            }

            private function dbQueryData(event:SQLEvent):void
            {
                trace("SQLite 数据插入完成");

                stmt.removeEventListener(SQLEvent.RESULT, dbQueryData);
                stmt.text = "SELECT Symbol,Name FROM stockdailywatch";
                stmt.execute(-1, new Responder(dbShowData, dbErrorHandler));
            }

            private function dbShowData(result:SQLResult):void
            {
                trace("查询成功"+result.rowsAffected);


                if(result.data!=null )
                {
                    trace(result.data.length + "个结果");
                    var c:ArrayCollection = new ArrayCollection(result.data);
                    var numResults:int =result.data.length;
                    this.dgStockWatch.dataProvider = c;
                }

            }




        ]]>
    </fx:Script>
    <mx:ViewStack x="27.8" y="32.4" id="viewDataSource" width="59" height="20">
        <s:NavigatorContent label="local" width="100%" height="100%">
            <s:Label>
                remote
            </s:Label>
        </s:NavigatorContent>
        <s:NavigatorContent label="remote" width="100%" height="100%">
            <s:Label>
                local
            </s:Label>
        </s:NavigatorContent>
    </mx:ViewStack>
    <s:CheckBox x="126" y="28" label="Local Data Source" id="cbLocal" click="cbLocal_changeHandler(event)"/>
    <s:Button x="285" y="28" label="打开 SQLite 数据库文件" id="btnOpen" click="btnOpen_clickHandler(event)"/>
    <mx:DataGrid x="27" y="79" width="643" height="145" id="dgStockDaily">
        <mx:columns>
            <mx:DataGridColumn headerText="列 1" dataField="col1"/>
            <mx:DataGridColumn headerText="列 2" dataField="col2"/>
            <mx:DataGridColumn headerText="列 3" dataField="col3"/>
        </mx:columns>
    </mx:DataGrid>
    <mx:DataGrid x="27" y="246" width="643" id="dgStockWatch" editable="true">
        <mx:columns>
            <mx:DataGridColumn headerText="ID" dataField="ID"/>
            <mx:DataGridColumn headerText="Symbol" dataField="Symbol"/>
            <mx:DataGridColumn headerText="Name" dataField="Name"/>
        </mx:columns>
    </mx:DataGrid>
    <mx:DataGrid x="27" y="412" width="643" id="dgMarketDaily">
        <mx:columns>
            <mx:DataGridColumn headerText="列 1" dataField="col1"/>
            <mx:DataGridColumn headerText="列 2" dataField="col2"/>
            <mx:DataGridColumn headerText="列 3" dataField="col3"/>
        </mx:columns>
    </mx:DataGrid>



</s:WindowedApplication>

本文链接

Flex AIR: 使用透明 NativeWindow 窗体呈现 Line Chart 的一个 bug （Exception in CartesianChart/updateMultipleAxesStyles）

2010-06-18T01:10:00Z

经过昨天一整天的反复试验、排错和线上检索，发现 AIR 在使用透明（transparent=true, showFlexChrome=false）的 NativeWindow 包裹一个含有 mx:LineChart 组件的 Window 窗体时，只要 mxml 文中出现任一个 <mx:LineChart/> 标记，就会报告以下异常，然后程式终止运行：

TypeError: Error #1009: Cannot access a property or method of a null object reference.
at mx.charts.chartClasses::CartesianChart/updateMultipleAxesStyles()[E:\dev\4.0.0\frameworks\projects\datavisualization\src\mx\charts\chartClasses\CartesianChart.as:2598]
at mx.charts.chartClasses::CartesianChart/commitProperties()[E:\dev\4.0.0\frameworks\projects\datavisualization\src\mx\charts\chartClasses\CartesianChart.as:1360]
at mx.core::UIComponent/validateProperties()[E:\dev\4.0.0\frameworks\projects\framework\src\mx\core\UIComponent.as:7772]
at mx.managers::LayoutManager/validateProperties()[E:\dev\4.0.0\frameworks\projects\framework\src\mx\managers\LayoutManager.as:572]
at mx.managers::LayoutManager/doPhasedInstantiation()[E:\dev\4.0.0\frameworks\projects\framework\src\mx\managers\LayoutManager.as:700]
at mx.managers::LayoutManager/doPhasedInstantiationCallback()[E:\dev\4.0.0\frameworks\projects\framework\src\mx\managers\LayoutManager.as:1072]

据说是因为 Flex 内部代码中一个叫做 hslen 的对象取不到 horizontalAxisStyleName 的 len 引起的。莫名其妙。

更莫名奇妙的是，在一个比较简单的 AIR project 里使用相同参数配置是没有出现这个现象的。唯一的区别是发生异常的前者使用一个从文件中读取的 XML 作为这个 Line Chart 的数据源，没有发生异常的后者使用定义 XML 的方式作为这个 Line Chart 的数据源，虽然两份 XML 文本是一致的，参数配置是一致的，除数据源外的代码是一致的，但是结果截然不同。

看来不仅与透明窗体有关，也跟数据源定义方式、跟程式规模（SWF解压后占用的字节规模）有关。

在 fx:Script 里声明一个 LineChart 对象不会报异常，然而这样是不能把图形呈现出来的。

解决办法只能是不使用透明的 NativeWindow 包裹，直接对 Window 窗体实施 open() 调用。虽然这样不能去掉 OS 的镶边、不能做不规则外形的透明窗体，但是至少可以把图形呈现出来。

在Google上搜寻相关问题只得三个结果，而且自2009年2月至今都是未解之谜。百度就一个结果都没有。看来这是 Flex AIR 长久的 bug 了。

调试环境是 AIR 2.02, 1.5, Flash Builder 4.0 Premium.

本文链接

Flex AIR：用 mx:Image 实现的动态图片按钮

2010-06-14T09:39:00Z

Spark 主题的 Button 控件在实现动态图片按钮时需要借助 Flash Catalyst 软件把每个图片转换成对应的 mxml 外观文本，不论加载效率，这种做法的门槛似乎有点高。本文使用一大一小两个PNG图片文件实现动态效果，这种方式比较原始，门槛比较低。但笔者估计，这种方式在内存加载效率上可能远不如 Spark 主题推荐的方式。

ButtonTest.mxml 的内容如下：

ImageButtonStyle.as 的内容如下：

package nonamecat.common.style
{
    import flash.events.MouseEvent;
    import mx.controls.Image;

    /**
     * 图像按钮的辅助行为
     */
    public class ImageButtonStyle
    {
        /**
         * 表示鼠标松开按键
         */
        public static var UP:int = -1;

        /**
         * 表示鼠标按下按键
         */
        public static var DOWN:int = 1;

        /**
         * 表示鼠标覆盖对象
         */
        public static var OVER:int = 2;

        /**
         * 表示鼠标离开对象
         */
        public static var OUT:int = 0;

        public function ImageButtonStyle()
        {
        }

        /**
         * 当鼠标移动经过对象上的时候激活的事件
         *
         * @param event 鼠标事件
         * @param imageUrl 用于替换的图片的 Url
         * @param width 用于替换的图片的宽度
         * @param height 用于替换的图片的高度，如果忽略，则视为与宽度一致
         */
        public static function onMouseMove(event:MouseEvent, imageUrl:String, width:Number, height:Number=0):void
        {
            var button:Image = event.currentTarget as Image;
            if(button!=null)
            {
                var state:int;
                if(event.localX<=0||event.localX>=button.width||event.localY<=0||event.localY>=button.height)
                {
                    state = OUT;
                }
                else
                {
                    state = OVER;
                }

                if(button.data!= state)
                {
                    button.data = state;
                    button.source=imageUrl;

                    var oldWidth:Number = button.width;
                    var oldHeight:Number = button.height;
                    var newWidth:Number = width;
                    var newHeight:Number = height == 0 ? width : height;

                    button.width=newWidth;
                    button.height=newHeight;
                    button.x=button.x-int((newWidth-oldWidth)/2);
                    button.y=button.y-int((newHeight-oldHeight)/2);

                }
            }

        }

        /**
         * 当鼠标点击对象时激活的事件
         *
         * @param button 图像按钮对象
         * @param event 鼠标事件
         */
        public static function onClick(event:MouseEvent):void
        {
            var button:Image = event.currentTarget as Image;
            if(button!=null)
            {
                var state:int;
                if(event.buttonDown)
                {
                    state = DOWN;
                }
                else
                {
                    state = UP;
                }
                button.data = state;
                button.x=button.x+3*state;
                button.y=button.y+3*state;
            }


        }
    }
}

本文链接

Flex AIR：Line Chart 示例－从 XML 原始数据运算得出增长率图表

2010-06-14T04:08:00Z

从 XML 原始数据运算得出增长率图表，主要方法是遍历 XML 子节点。通过 reverse() 函数还可以先把 XML 倒序排列，便于以不同角度观察数据。

效果如下图：

ChartTest.mxml 内容如下：

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
                       xmlns:s="library://ns.adobe.com/flex/spark"
                       xmlns:mx="library://ns.adobe.com/flex/mx"
                       xmlns:flexlib="http://code.google.com/p/flexlib/"
                       creationComplete="init()"
                       width="800" height="450" >
    <fx:Declarations>
        
    </fx:Declarations>
    <fx:Script>
        <![CDATA[
            import mx.charts.HitData;
            import mx.charts.series.items.LineSeriesItem;

            /**
             * XML 数据源。
             */
            private var xml:XML =
                <data>
                    <stock>
                        <term>Season 1</term>
                        <value1>10</value1>
                        <value2>40</value2>
                    </stock>
                    <stock>
                        <term>Season 2</term>
                        <value1>20</value1>
                        <value2>30</value2>
                    </stock>
                    <stock>
                        <term>Season 3</term>
                        <value1>25</value1>
                        <value2>35</value2>
                    </stock>
                    <stock>
                        <term>Season 4</term>
                        <value1>50</value1>
                        <value2>25</value2>
                    </stock>
                </data>;

            /**
             *  AIR 主窗口初始化，为 Line Chart 绑定数据源。
             */
            protected function init():void
            {
                this.ctLine.dataProvider = this.xml.children();
                this.calcIncrement(this.xml);
                this.ctLineIncrease.dataProvider = this.xml.children();
            }

            /**
             * 令 XML 数据源倒序排列。
             *
             * 用法：
             * var result:XML = <data></data>;
             * result = this.reverse(this.xml, result);
             *
             * @param source XML 数据源。
             * @param root 倒序排列后的 XML 结果，须传入一个顶层节点，以便遍历数据源子节点后依次添加到此顶层节点。
             *
             *
             *
             */
            private function reverse(source:XML, root:XML):XML
            {
                var list:XMLList = source.children();
                for(var i:int=list.length()-1;i>-1;i--)
                {
                    root.appendChild(list[i]);
                }
                return root;
            }

            /**
             * 计算 XML 数据源中前后两个 value 节点的值的增长率，储存到 increase 节点。
             * @ram source XML 数据源
             */
            private function calcIncrement(source:XML):void
            {
                var list:XMLList = source.children();
                for(var i:int=list.length()-1;i>-1;i--)
                {
                    if(i>0)
                    {
                        var next:XML = list[i];
                        var prior:XML = list[i-1];
                        var increase1:Number = Number((next.value1 - prior.value1))/Number(prior.value1);
                        next.increase1 = increase1;


                        var increase2:Number = Number((next.value2 - prior.value2))/Number(prior.value2);
                        next.increase2 = increase2;
                    }
                    else
                    {
                        list[i].increase1 = 0;
                        list[i].increase2 = 0;
                    }
                    trace(list[i].value1 + " " + list[i].increase1 + "\t" + list[i].value2 + " " + list[i].increase2);
                }
            }

            /**
             * 原始数据 Line Chart 的数值提示
             */
            protected  function ctLine_dataTips(hd:HitData):String {
                var curObj:Object = hd.item;
                var curSeries:LineSeries = LineSeries(hd.chartItem.element); // 获得当前的Series
                var value:Number = Number((hd.chartItem as LineSeriesItem).yValue); // 获得当前指向的值
                return curObj.term + "\n" + curSeries.displayName + "\n = " + value;
            }

            /**
             * 增长率 Line Chart 的数值提示
             */
            protected  function ctLineIncrease_dataTips(hd:HitData):String {
                var curObj:Object = hd.item;
                var curSeries:LineSeries = LineSeries(hd.chartItem.element); // 获得当前的Series
                var increase:Number = Number((hd.chartItem as LineSeriesItem).yValue); // 获得当前指向的值
                return curObj.term + "\n" + curSeries.displayName + "\n = " + Number(increase*100).toFixed(2) + "%";
            }

        ]]>
    </fx:Script>
    
    <mx:LineChart x="80" y="60" width="300" height="300" id="ctLine" showDataTips="true" dataTipFunction="ctLine_dataTips">
        <mx:series>
            <mx:LineSeries displayName="Value 1" yField="value1"/>
            <mx:LineSeries displayName="Value 2" yField="value2"/>
        </mx:series>
        
        <mx:horizontalAxis>
            <mx:CategoryAxis categoryField="term" title="Season"/>
        </mx:horizontalAxis>
    </mx:LineChart>
    
    <mx:Legend x="5" y="5" dataProvider="{ctLine}" id="ctLegendValue"/>

    
    <mx:LineChart x="400" y="60" width="300" height="300" id="ctLineIncrease" showDataTips="true" dataTipFunction="ctLineIncrease_dataTips">
        <mx:series>
            <mx:LineSeries displayName="Increase Rate 1" yField="increase1"/>
            <mx:LineSeries displayName="Increase Rate 2" yField="increase2"/>
        </mx:series>
        
        <mx:horizontalAxis>
            <mx:CategoryAxis categoryField="term" title="Season"/>
        </mx:horizontalAxis>
    </mx:LineChart>
    
    <mx:Legend x="385" y="5" dataProvider="{ctLineIncrease}" id="ctLegendIncrease"/>
</s:WindowedApplication>

本文链接

Flex AIR：Line Chart 示例－用 XML 画图表很简单

2010-06-13T23:03:00Z

Line Chart 示例

效果如下图：

ChartTest.mxml 内容如下：

其中数据源 dataProvider 里的 XML 也可以在 fx:Script 区域内用 ActionScript 代码实现。

本文链接

Flex: 抓取网页，通过 XML 获取部分内容

2010-06-12T05:40:00Z

样本程式的目的是到证券之星网站取得宇通客车52周和104周最高报价和最低报价。由于证券之星的网页格式不符合XML格式规范，故此不能把抓取回来的网页直接转换为 XML，需要先经过文本截取处理。Flex 利用 E4X 操作 XML 甚为方便。

AIR 运行效果如下图：

ClawTest.mxml 内容如下：

1 <?xml version="1.0" encoding="utf-8"?>
2 <s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
3                        xmlns:s="library://ns.adobe.com/flex/spark"
4                        xmlns:mx="library://ns.adobe.com/flex/mx">
5
6     <fx:Script>
7         <![CDATA[
8
9             // “获取”按钮点击事件
10             protected function btnGet_clickHandler(event:MouseEvent):void
11             {
12                 var request:URLRequest = new URLRequest("http://quote.stockstar.com/stock/sh_600066.htm");
13                 var loader:URLLoader = new URLLoader();
14                 loader.load(request);
15                 loader.addEventListener(Event.COMPLETE,onCompleteHandler);
16             }
17
18             // 当网页载入完毕时触发的事件
19             private function onCompleteHandler(event:Event):void
20             {
21                 // 网页内容储存在 event.target.data 里
22                 // 这个 data 既可以被封装为 String，也可以被封装为 XML
23                 // 如果这个网页的 HTML 标记不规范、不符合 XML 格式，封装为 XML 的时候就会报错
24                 var data:String = new String(event.target.data);
25
26                 // 第一次截取片段
27                 var begin:int = data.indexOf("<div class=\"m_foot\">");
28                 var end:int = data.indexOf("<div class=\"m_foot_more\">");
29                 var cutdiv:String = data.substring(begin,end);
30
31                 // 第二次截取片段
32                 begin = cutdiv.indexOf("<table width=\"97%\" ");
33                 end = cutdiv.indexOf("</table>");
34                 var cutable:String = cutdiv.substring(begin, end+8);
35
36                 // 转换为 XML，如果片段内容格式不符合 XML 规范，就会报错
37                 var xml:XML = new XML(cutable);
38
39                 // 取得想要的内容
40                 var high52:String = xml.tr[4].td[1];
41                 var low52:String = xml.tr[4].td[2];
42                 var high104:String = xml.tr[5].td[1];
43                 var low104:String = xml.tr[5].td[2];
44
45                 // 呈现结果
46                 this.txtBox.text = high52 + "\n" + low52 + "\n" + high104 + "\n" + low104;
47             }
48         ]]>
49     </fx:Script>
50
51     <fx:Declarations>
52         
53     </fx:Declarations>
54     <s:TextArea x="95" y="49" id="txtBox" editable="true" enabled="true" width="352" height="226"/>
55     <s:Button x="237" y="318" label="获取" id="btnGet" enabled="true" click="btnGet_clickHandler(event)"/>
56 </s:WindowedApplication>
57

本文链接

博客园_广氏波罗猫 技术研习社

AirExcel －用于导出 Excel 2007 文件的 Flex AIR 组件 初版发布

Flex SQLite Batch Insert Datas from Array

Flex 遍历 ArrayCollection, Array

Flex SQLite: 一次执行多个SQL，查询两个表的数据，导入datagrid

Flex AIR SQLite

Flex AIR: 使用透明 NativeWindow 窗体呈现 Line Chart 的一个 bug （Exception in CartesianChart/updateMultipleAxesStyles）

Flex AIR：用 mx:Image 实现的动态图片按钮

Flex AIR：Line Chart 示例－从 XML 原始数据运算得出增长率图表

Flex AIR：Line Chart 示例－用 XML 画图表很简单

Flex: 抓取网页，通过 XML 获取部分内容

博客园_广氏波罗猫技术研习社

AirExcel －用于导出 Excel 2007 文件的 Flex AIR 组件初版发布